configurations {
    javadoc
}

dependencies {
    javadoc "org.umlgraph:umlgraph:5.6.6"
}

afterEvaluate {
    def debugVariant = android.applicationVariants.find { variant ->
        variant.name == "debug"
    }

    task javadoc(type: Javadoc) {
        title = "Beem javadoc"
        dependsOn "generateDebugSources"
        source = debugVariant.javaCompile.source
        includes = ["**/com/beem/project/beem/**",
                    "**/com/google/android/apps/iosched/util/**"]
        classpath = files(android.getBootClasspath(),
                debugVariant.javaCompile.classpath)

        // remove doc lint because some generated code doesn't pass for it
        options.addStringOption "Xdoclint:none", "-quiet"
        options.docletpath = configurations.javadoc.files.asType(List)
        options.doclet = "org.umlgraph.doclet.UmlGraphDoc"
        options.addStringOption "inferrel", "-quiet"
        options.addStringOption "inferdep", "-quiet"
        options.addStringOption "hide", "java.*"
        options.addStringOption "collpackages", "java.util.*"
        options.addStringOption "qualify", "-quiet"
        options.addStringOption "types", "-quiet"
        options.addStringOption "visibility", "-quiet"
        options.addStringOption "postfixpackage", "-quiet"
        options.addStringOption "nodefontsize", "9"
        options.addStringOption "nodefontpackagesize", "7"
    }

}