--- /dev/null Thu Jan 01 00:00:00 1970 +0000
+++ b/app-misc/pycarddav/Manifest Tue Mar 25 18:26:56 2014 +0100
@@ -0,0 +1,1 @@
+DIST pyCardDAV-0.6.1.tar.gz 34158 SHA256 32e223ccd7b243024f9d8da46b6f97350d520e204c5b80f8266698c1071e38e0 SHA512 a55dc8a265be03533f17b4698e797f679ed46e8860cfa4c140f753a2719b2e8d69978aa6a86ab87b622d5be5ddd015c3301d9433564c8ef4cb5eee53543740d8 WHIRLPOOL 496227084e90bbe1b1d1d368a2ba7339facd268239c9ae70b8774b4dc17efb19a0d13b3a4a4982c9875ff3cd86b9b3ab3bb1bb4dcc27ac34c723e9dbf6209a51
--- /dev/null Thu Jan 01 00:00:00 1970 +0000
+++ b/app-misc/pycarddav/metadata.xml Tue Mar 25 18:26:56 2014 +0100
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer><email>da_risk@geekorum.com</email></maintainer>
+</pkgmetadata>
--- /dev/null Thu Jan 01 00:00:00 1970 +0000
+++ b/app-misc/pycarddav/pycarddav-0.6.1.ebuild Tue Mar 25 18:26:56 2014 +0100
@@ -0,0 +1,41 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+PYTHON_REQ_USE="sqlite"
+
+PYTHON_COMPAT=( python2_6 python2_7 )
+
+inherit distutils-r1
+
+DESCRIPTION="A CardDAV based address book tool"
+HOMEPAGE="http://lostpackets.de/pycarddav/"
+SRC_URI="https://lostpackets.de/pycarddav/downloads/pyCardDAV-${PV}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~x86 ~amd64"
+SLOT="0"
+IUSE=""
+
+S=$WORKDIR/pyCardDAV-$PV
+
+DEPEND="
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ dev-python/urwid[${PYTHON_USEDEP}]
+ dev-python/vobject[${PYTHON_USEDEP}]
+ dev-python/pyxdg[${PYTHON_USEDEP}]
+ virtual/python-argparse"
+RDEPEND="${DEPEND}"
+
+DOCS=( pycard.conf.sample README.rst )
+
+pkg_postinst() {
+ ewarn "Copy and edit the supplied pycard.conf.sample file"
+ ewarn "(default location is ~/.pycard/pycard.conf)."
+ ewarn "Beware that only you can access this file,"
+ ewarn "if you have untrusted users on your machine,"
+ ewarn "since the password is stored in cleartext."
+}
--- a/dev-java/icedtea/Manifest Sun Feb 23 17:27:03 2014 +0100
+++ b/dev-java/icedtea/Manifest Tue Mar 25 18:26:56 2014 +0100
@@ -1,10 +1,18 @@
DIST icedtea-2.4-cacao-e215e36be9fc.tar.gz 4263463 SHA256 4966514c72ee7ed108b882d9b6e65c3adf8a8f9c2dccb029f971b3c8cb4870ab SHA512 2f27fbdd64d2b6ea2fa39c55bcd2344c49d02269492bd1aa1b334555bc66aa59d021bce12af60fdbf81e810fa4b8e488354025bf0f770ba4582c85592cd6c22f WHIRLPOOL 7865532185aa0a6e5c6caf8cb7affefdfb473b1c5686ada1f2e071776b4faae153c2086c2c2df9e2b2b2124b629433b849bd10f82cf8f8e3f0e7aa84b5bfebba
+DIST icedtea-2.4-corba-3594dbde270d.tar.gz 1442141 SHA256 d1f97e143fe94ae3a56b45bb5a90f8ab10ec2be4ff770a788f0a1ac677e27a7d SHA512 06bfd82b188dbfeb2f05bc4fdc8585a9ce66762f835052a8bfe5f4ebc2d4eb90c966bd6766825b9d68b7425a2d7af27311da1f3c7c37ce4a36e81b85745cb447 WHIRLPOOL 4eccb70e42d3c5232aeea74681e4c0e91c160dabdc372b594a30a222326e18db18279ab8e3774fc0ac55a916b854312e578f1e1ef0c3bd4da2d55639b4ce83d8
DIST icedtea-2.4-corba-8ed5df839fbc.tar.gz 1440538 SHA256 7fab9af64ffcdf635a6fed5abf78cffd1f64be1f3827a1aaf3a0e5e1fdbc599c SHA512 3fff60fc85dc4b27991363c067637b81557d6ca65131296e44c77172736007a3c6221d48f803168677937d3941e7bad585c229d833f67de53b51f256ae2b3e6c WHIRLPOOL 35c223c1821fe01a28d3a9463521b1fd2cb7a946517451e2a42191b038de0ade0632086c9dfeabcd9d6ab9398d3ab229db8ad96244440d5158493d8f74747cc9
+DIST icedtea-2.4-hotspot-2cb58882dac3.tar.gz 9628431 SHA256 d8c1681ae76e660c1888065933cedbbc1309869c7a2fb98f07c424716d5ebaf9 SHA512 c27c90ab523a0cd438d4850e8762e7047478332fbbee0cf61b07214dafff5db9d6d41c95cc165993458c83ffd91458f1b2f0ff7578f34bfe74a1ff912a587127 WHIRLPOOL 5787bdb3e83a20a2e9296d0f4bacb172c89cf27775f8754fc2a2cdfc3e4a6adee4f7b1af9810c97e0e987cc65e557b5a1edc5238b7adf503ad5147896c6fc997
DIST icedtea-2.4-hotspot-b59e02d9e72b.tar.gz 9626517 SHA256 b7d7e01d7ab9e49b68aa29b55355a019d71f9ae5cabb4ea7378b55855a07df57 SHA512 275d5c67499dcf553f3c74e84f173947ce103c20b8a18a19c20860829e3d1fa6afa1a45e986c6fc1658d73ccb6f4b0210dd46853541901de06f036cc137d2fdd WHIRLPOOL 7feb88c00e10baf205c33afe9aceb5452974fe1e7985895405e1021ce59140600830404565f7fa98fae4c0ec2ac70cd3368460ccf1d0b6c1cbe3d51c921f9d0c
DIST icedtea-2.4-jamvm-ac22c9948434e528ece451642b4ebde40953ee7e.tar.gz 316422 SHA256 4662da1fe3e0e11d8fa685c7f2fc748576b9f3d3e37dc56b798dd6a5bd6b61e7 SHA512 a8132ce0f97f5ba090b12aad847072861f8913fe1fdc3a540e9e353b0d9ddc564a96ab2bcbfa27a7068bba606428d7dc9de4f7ad668e546151657f9ddcfc28ad WHIRLPOOL 8e274825bec5c47787eda0e25a0bc4a586a8938c1fa3c4f0c4f7c04e679d28458a61f45bfa62b255a630a4ca3a5c5d1aa3436086cba92ee7a43d3a2b8684e330
DIST icedtea-2.4-jaxp-8f220f7b51c7.tar.gz 3889719 SHA256 cec41aebd42f4c8caba9c24c306ba78e8cf5da3d23da1604b98753340a2719ca SHA512 6f961a1af3aa5ada703371c24089c91161bd6d7345603bf61bcf8eb72983ce7a38f07266ef98148f438bf7a1520c4bdcfd7e5bf026191e1a431e54c4392f571e WHIRLPOOL 8ba2b52ae10af20f2da91fa8df0af7c6d3757e29b579759c9bc5217354647995b57514bbfaa9e5a2ea17ecd6d9425bf37f8017b0c29ef6bb7e53e363e3b3d8cf
+DIST icedtea-2.4-jaxp-8fe156ad49e2.tar.gz 3889958 SHA256 0a2a40186cedfbeb8f87b0bc86bea2830943943081d4289fc74f7a783b2e1af3 SHA512 5bc6e75482976e014e191a4952b6598a979fb440643916f5de741be8662e6dcdb224ac7dcca848cb80f2181e9d175d7cfa6cc678c1472ec5bec1adf249324815 WHIRLPOOL 3c377bcb871b99b14a343d01644b914952265d9dc66cf6e5e8c2707301db5b0457c0c3041dc8a6856225ff1c7e500eb12dd3d3dae7aa7fa026f7c230dcef3155
+DIST icedtea-2.4-jaxws-32ea8b1ed91a.tar.gz 2769247 SHA256 08a169b6b02883759ec7a412aa91aa3e37480761cb50b95d092dbcdb2fc9a3d0 SHA512 4eaf5af04e65033ad65b04e5d6dd4c91c007d314230990856abb9a551b54c03dc7c26cb8e2da070558b6d2ff5a1c6d5af53dbc966eda352d873771629aca51a6 WHIRLPOOL 791a500d4076c3c542f00ec41e772bbae53a36bc6043edb64ffe459096ba136a08aa4f7dd972a6f1861ef48c3ce3003c3934c6ff29c9a456e2b10a65690b10a6
DIST icedtea-2.4-jaxws-652eb396f959.tar.gz 2763848 SHA256 fb9c22e92c2a056917b7b5dce6905a01ab2e904cbc3c1c6badcc470d22136518 SHA512 83c2cc366bf8a96b1174b42ce4048a5f603e672c8dfe9150c8e70d4d590a702c12365ffc07185d0dcbca918a2e21238211fb42724dabd37dc7db2004a23f0a1d WHIRLPOOL bda9dc09d95ce8604169e263a2cd3dd353791267e0e4540a016b5f78a3cf6274cafc1aaa2a6dee10a89405690c987f9b6a2ed7d8fec5a10a226f7a1535848af4
DIST icedtea-2.4-jdk-7958751eb9ef.tar.gz 45252720 SHA256 4df06346d197180bbb9d182e3ebc9ab6386562199d9898d057d0df75566349fe SHA512 6c54d69e4afe65ce4738d30254a71bed1ac6c028a752d8be2310cb9d06b6d5a77db357c838b6df5246624f7f0168c5224c9ce260de4f49c6b92ae8b4e9413f84 WHIRLPOOL eefdcf720bcdccdecb4166bcfdbb3d81d28c2b2a2def00f01813cf9c9d314f75bef8b32eba66252f31bdb1396f320af0b5004c63e5cf70dd8bcbde0350d79d52
+DIST icedtea-2.4-jdk-9db88c18e114.tar.gz 39949000 SHA256 285e5b8ccbb29f3f9f9ea9ea7856d1ed97465c57d091fbcd9b2e55a1ffbb543e SHA512 3aeacd02af8263b1168c238045973d57e33aea94a13e95527911f993ffd941423d0db667cd5dd786509c7625ceafdc021cb410573744a93b876a8717d47cfc50 WHIRLPOOL 075f632a800939dc804b850037e26f72428ee086145d81e122404c6c017edbe833fcc42f4bf6942e64be2106da20af40764acbd421f11832482404a773ba5546
DIST icedtea-2.4-langtools-3c8eb52a32ea.tar.gz 2321300 SHA256 462ad61fd34708c90362f9e3d3c432b9246833ea8ff0d8a14955ae386bce4a91 SHA512 917e313dc897ea8548616ad766bc5b937eafe1219b9ff344c89bee02d3432f21559f6a02027031ff4f6b0957be4e8ea41b3f646f86a09d7f1ebe809639896b95 WHIRLPOOL 0d0b4a973d6e334176790190e467cfb8f9096119fcab8f63d4aa3689b3bd434db4de842dfe7ec4dfce819028e07df1491fc43c4825a75f33f46cd8d08de1b981
+DIST icedtea-2.4-langtools-dabd37b7e295.tar.gz 2299222 SHA256 86cb370ce2084c4b699d8c002ebe6c026e86206ffa82a2f3d7906aadb94ed79f SHA512 f6b650431f20758b0f17bc2760e1426e622def620fff80874146e865e2d87d2ce265926c20282489a245df575a87618265dd83a3eb3d8443938f175a89f2c302 WHIRLPOOL 6680ee66f26a85c7aeaa68fc86f9f071a4b77316ddac28c04408be094365b9ad41d61f1867db4f538ea20e596b7905e98323eb0ff7d80a9171529b836d6e396b
+DIST icedtea-2.4-openjdk-410eb7fef869.tar.gz 137063 SHA256 2de151c7275d91ef082e63fcc0957c5f9290404ec6e20ecfa1e752e16bfab707 SHA512 135a87d7831d5803b495d8908cab13d9f87134a3eb696684b27aea7fc1ef35677594d4037b44f19b317300555d42c05a569a3a3928458e9787f34cbcf8fce300 WHIRLPOOL c03bef503cf6ebd1eec165eb73d33cf9eb208487d52fe87921d503c6ee1be424afd6717efd9c0655409facc675f8056347d0f51db4561f2b188145051a501be6
DIST icedtea-2.4-openjdk-e2f5917da3c1.tar.gz 136580 SHA256 75a18abd117e3295c6de4d3450f0094a9abc08f2168e2911bce25d1e153107b9 SHA512 b1657f421ea64d076c3738533039b769de18c5ceec8c0e76cec5f12fe7c79c0bb585cc4bfeebe038dfae30f648287b79d8660e1decb907739ff213382504fe48 WHIRLPOOL 34e946d78d7c18d8ba91a7f7b996079fe98413268c33a8e0f29b7dc64843b6c0981ea33148981c8afa73fbfc69e51bfd09f0f5f2af876e54a54c18ac3eac9c17
DIST icedtea-2.4.3.tar.xz 3417116 SHA256 9289d25867b39756d62ba16eda5834655609a6962e0eaf2edacc04e3b629c806 SHA512 700496b3e09fd0a72fd672e91b9fe4d7296db3bdd1f344582d72cad64ef4aa5fe12ee13150d9555ebce90024c9aa8e9cc630acc66b4bf9c43a264091a441df2c WHIRLPOOL 88986669a6f1d00d453f509874add60c60a6aff257808d24ac7fa625c8ca238ce8be0167019a6e472132c5a0c6eea07462714c2dffc8b6c72b9adc039342d91a
+DIST icedtea-2.4.5.tar.xz 3420624 SHA256 d3f96413c77efa400947d1c5e85bb55fdb0c36d0adb8802f0ca2b283855d305b SHA512 6a499bcffd68b2cf41aead93178057d23d89d554e89765e3041ce6cd494f7097e6cb5358b6718199b17cf86486b65868e86be6f0b3fc0d83f3ff8568a931a41f WHIRLPOOL c210fec92422ad98510d06e42ac3daca11cc8feef16a9671a4be929bb3c08ea114f2599f7aadce9d6c8d8cc3b82da30d19915359a1423cf1c5a1a6ad1c18b233
--- /dev/null Thu Jan 01 00:00:00 1970 +0000
+++ b/dev-java/icedtea/icedtea-7.2.4.5.ebuild Tue Mar 25 18:26:56 2014 +0100
@@ -0,0 +1,364 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/icedtea/icedtea-7.2.4.5.ebuild,v 1.1 2014/02/03 08:49:54 sera Exp $
+# Build written by Andrew John Hughes (gnu_andrew@member.fsf.org)
+
+# *********************************************************
+# * IF YOU CHANGE THIS EBUILD, CHANGE ICEDTEA-6.* AS WELL *
+# *********************************************************
+
+EAPI="5"
+
+inherit java-pkg-2 java-vm-2 pax-utils prefix versionator virtualx
+
+ICEDTEA_VER=$(get_version_component_range 2-)
+ICEDTEA_BRANCH=$(get_version_component_range 2-3)
+ICEDTEA_PKG=icedtea-${ICEDTEA_VER}
+CORBA_TARBALL="3594dbde270d.tar.gz"
+JAXP_TARBALL="8fe156ad49e2.tar.gz"
+JAXWS_TARBALL="32ea8b1ed91a.tar.gz"
+JDK_TARBALL="9db88c18e114.tar.gz"
+LANGTOOLS_TARBALL="dabd37b7e295.tar.gz"
+OPENJDK_TARBALL="410eb7fef869.tar.gz"
+HOTSPOT_TARBALL="2cb58882dac3.tar.gz"
+CACAO_TARBALL="e215e36be9fc.tar.gz"
+JAMVM_TARBALL="jamvm-ac22c9948434e528ece451642b4ebde40953ee7e.tar.gz"
+
+CORBA_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-corba-${CORBA_TARBALL}"
+JAXP_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-jaxp-${JAXP_TARBALL}"
+JAXWS_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-jaxws-${JAXWS_TARBALL}"
+JDK_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-jdk-${JDK_TARBALL}"
+LANGTOOLS_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-langtools-${LANGTOOLS_TARBALL}"
+OPENJDK_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-openjdk-${OPENJDK_TARBALL}"
+HOTSPOT_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-hotspot-${HOTSPOT_TARBALL}"
+CACAO_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-cacao-${CACAO_TARBALL}"
+JAMVM_GENTOO_TARBALL="icedtea-${ICEDTEA_BRANCH}-${JAMVM_TARBALL}"
+
+DESCRIPTION="A harness to build OpenJDK using Free Software build tools and dependencies"
+HOMEPAGE="http://icedtea.classpath.org"
+SRC_PKG="${ICEDTEA_PKG}.tar.xz"
+SRC_URI="
+ http://icedtea.classpath.org/download/source/${SRC_PKG}
+ http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/archive/${OPENJDK_TARBALL}
+ -> ${OPENJDK_GENTOO_TARBALL}
+ http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/corba/archive/${CORBA_TARBALL}
+ -> ${CORBA_GENTOO_TARBALL}
+ http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/jaxp/archive/${JAXP_TARBALL}
+ -> ${JAXP_GENTOO_TARBALL}
+ http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/jaxws/archive/${JAXWS_TARBALL}
+ -> ${JAXWS_GENTOO_TARBALL}
+ http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/jdk/archive/${JDK_TARBALL}
+ -> ${JDK_GENTOO_TARBALL}
+ http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/hotspot/archive/${HOTSPOT_TARBALL}
+ -> ${HOTSPOT_GENTOO_TARBALL}
+ http://icedtea.classpath.org/hg/release/icedtea7-forest-${ICEDTEA_BRANCH}/langtools/archive/${LANGTOOLS_TARBALL}
+ -> ${LANGTOOLS_GENTOO_TARBALL}
+ http://icedtea.classpath.org/download/drops/cacao/${CACAO_TARBALL} -> ${CACAO_GENTOO_TARBALL}
+ http://icedtea.classpath.org/download/drops/jamvm/${JAMVM_TARBALL} -> ${JAMVM_GENTOO_TARBALL}"
+
+LICENSE="Apache-1.1 Apache-2.0 GPL-1 GPL-2 GPL-2-with-linking-exception LGPL-2 MPL-1.0 MPL-1.1 public-domain W3C"
+SLOT="7"
+KEYWORDS="~amd64 ~ia64 ~x86"
+
+IUSE="+X +alsa cacao cjk +cups debug doc examples javascript +jbootstrap kerberos +nsplugin
+ +nss pax_kernel pulseaudio +source test +webstart"
+
+# Ideally the following were optional at build time.
+ALSA_COMMON_DEP="
+ >=media-libs/alsa-lib-1.0"
+CUPS_COMMON_DEP="
+ >=net-print/cups-1.2.12"
+X_COMMON_DEP="
+ >=dev-libs/atk-1.30.0
+ >=dev-libs/glib-2.26
+ media-libs/fontconfig
+ >=media-libs/freetype-2.3.5:2=
+ >=x11-libs/cairo-1.8.8:=
+ x11-libs/gdk-pixbuf:2
+ >=x11-libs/gtk+-2.8:2=
+ >=x11-libs/libX11-1.1.3
+ >=x11-libs/libXext-1.1.1
+ >=x11-libs/libXi-1.1.3
+ >=x11-libs/libXrender-0.9.4
+ >=x11-libs/libXtst-1.0.3
+ >=x11-libs/pango-1.24.5"
+X_DEPEND="
+ >=x11-libs/libXau-1.0.3
+ >=x11-libs/libXdmcp-1.0.2
+ >=x11-libs/libXinerama-1.0.2
+ x11-proto/inputproto
+ >=x11-proto/xextproto-7.1.1
+ x11-proto/xineramaproto
+ x11-proto/xproto"
+
+COMMON_DEP="
+ >=media-libs/giflib-4.1.6:=
+ >=media-libs/lcms-2.5
+ >=media-libs/libpng-1.2:=
+ >=sys-libs/zlib-1.2.3:=
+ virtual/jpeg:0=
+ javascript? ( dev-java/rhino:1.6 )
+ nss? ( >=dev-libs/nss-3.12.5-r1 )
+ pulseaudio? ( >=media-sound/pulseaudio-0.9.11:= )
+ kerberos? ( virtual/krb5 )
+ >=dev-util/systemtap-1"
+
+# cups is needed for X. #390945 #390975
+RDEPEND="${COMMON_DEP}
+ !dev-java/icedtea:0
+ X? (
+ ${CUPS_COMMON_DEP}
+ ${X_COMMON_DEP}
+ media-fonts/dejavu
+ cjk? (
+ media-fonts/arphicfonts
+ media-fonts/baekmuk-fonts
+ media-fonts/lklug
+ media-fonts/lohit-fonts
+ media-fonts/sazanami
+ )
+ )
+ alsa? ( ${ALSA_COMMON_DEP} )
+ cups? ( ${CUPS_COMMON_DEP} )"
+
+# Only ant-core-1.8.1 has fixed ant -diagnostics when xerces+xalan are not present.
+# ca-certificates, perl and openssl are used for the cacerts keystore generation
+# xext headers have two variants depending on version - bug #288855
+# autoconf - as long as we use eautoreconf, version restrictions for bug #294918
+DEPEND="${COMMON_DEP} ${ALSA_COMMON_DEP} ${CUPS_COMMON_DEP} ${X_COMMON_DEP}
+ || (
+ >=dev-java/gcj-jdk-4.3
+ dev-java/icedtea-bin:7
+ dev-java/icedtea-bin:6
+ dev-java/icedtea:7
+ dev-java/icedtea:6
+ )
+ app-arch/cpio
+ app-arch/unzip
+ app-arch/zip
+ app-misc/ca-certificates
+ dev-lang/perl
+ >=dev-libs/libxslt-1.1.26
+ dev-libs/openssl
+ virtual/pkgconfig
+ sys-apps/attr
+ sys-apps/lsb-release
+ ${X_DEPEND}
+ pax_kernel? ( sys-apps/paxctl )"
+
+PDEPEND="webstart? ( dev-java/icedtea-web:7 )
+ nsplugin? ( dev-java/icedtea-web:7[nsplugin] )"
+
+S="${WORKDIR}"/${ICEDTEA_PKG}
+
+pkg_setup() {
+ JAVA_PKG_WANT_BUILD_VM="
+ icedtea-7 icedtea-bin-7 icedtea7
+ icedtea-6 icedtea-bin-6 icedtea6 icedtea6-bin
+ gcj-jdk"
+ JAVA_PKG_WANT_SOURCE="1.5"
+ JAVA_PKG_WANT_TARGET="1.5"
+
+ java-vm-2_pkg_setup
+ java-pkg-2_pkg_setup
+}
+
+src_unpack() {
+ unpack ${SRC_PKG}
+}
+
+java_prepare() {
+ # For bootstrap builds as the sandbox control file might not yet exist.
+ addpredict /proc/self/coredump_filter
+
+ # icedtea doesn't like some locales. #330433 #389717
+ export LANG="C" LC_ALL="C"
+
+ # apply paxctl-ng patch
+ epatch "${FILESDIR}/${PN}-use-paxctl-ng.patch"
+}
+
+src_configure() {
+ local config bootstrap use_zero zero_config
+ local vm=$(java-pkg_get-current-vm)
+
+ # Whether to bootstrap
+ bootstrap="disable"
+ if use jbootstrap; then
+ bootstrap="enable"
+ fi
+
+ if has "${vm}" gcj-jdk; then
+ # gcj-jdk ensures ecj is present.
+ use jbootstrap || einfo "bootstrap is necessary when building with ${vm}, ignoring USE=\"-jbootstrap\""
+ bootstrap="enable"
+ local ecj_jar="$(readlink "${EPREFIX}"/usr/share/eclipse-ecj/ecj.jar)"
+ config="${config} --with-ecj-jar=${ecj_jar}"
+ fi
+
+ config="${config} --${bootstrap}-bootstrap"
+
+ # Use CACAO if requested
+ if use cacao; then
+ use_cacao="yes";
+ fi
+
+ # Always use HotSpot as the primary VM if available. #389521 #368669 #357633 ...
+ # Otherwise use CACAO
+ if ! has "${ARCH}" amd64 sparc x86 ; then
+ if has "${ARCH}" ppc ppc64 arm ; then
+ use_cacao="yes";
+ else
+ use_zero="yes";
+ fi
+ fi
+
+ # Turn on CACAO if needed (non-HS archs) or requested
+ if test "x${use_cacao}" = "xyes"; then
+ cacao_config="--enable-cacao";
+ fi
+
+ # Turn on Zero if needed (non-HS/CACAO archs) or requested
+ if test "x${use_zero}" = "xyes"; then
+ zero_config="--enable-zero";
+ fi
+
+ # OpenJDK-specific parallelism support. Bug #389791, #337827
+ # Implementation modified from waf-utils.eclass
+ # Note that "-j" is converted to "-j1" as the system doesn't support --load-average
+ local procs=$(echo -j1 ${MAKEOPTS} | sed -r "s/.*(-j\s*|--jobs=)([0-9]+).*/\2/" )
+ config="${config} --with-parallel-jobs=${procs}";
+ einfo "Configuring using --with-parallel-jobs=${procs}"
+
+ if use javascript ; then
+ config="${config} --with-rhino=$(java-pkg_getjar rhino-1.6 js.jar)"
+ else
+ config="${config} --without-rhino"
+ fi
+
+ unset JAVA_HOME JDK_HOME CLASSPATH JAVAC JAVACFLAGS
+
+ econf ${config} \
+ --with-openjdk-src-zip="${DISTDIR}/${OPENJDK_GENTOO_TARBALL}" \
+ --with-corba-src-zip="${DISTDIR}/${CORBA_GENTOO_TARBALL}" \
+ --with-jaxp-src-zip="${DISTDIR}/${JAXP_GENTOO_TARBALL}" \
+ --with-jaxws-src-zip="${DISTDIR}/${JAXWS_GENTOO_TARBALL}" \
+ --with-jdk-src-zip="${DISTDIR}/${JDK_GENTOO_TARBALL}" \
+ --with-hotspot-src-zip="${DISTDIR}/${HOTSPOT_GENTOO_TARBALL}" \
+ --with-langtools-src-zip="${DISTDIR}/${LANGTOOLS_GENTOO_TARBALL}" \
+ --with-cacao-src-zip="${DISTDIR}/${CACAO_GENTOO_TARBALL}" \
+ --with-jamvm-src-zip="${DISTDIR}/${JAMVM_GENTOO_TARBALL}" \
+ --with-jdk-home="$(java-config -O)" \
+ --with-abs-install-dir=/usr/$(get_libdir)/icedtea${SLOT} \
+ --disable-downloading --disable-Werror \
+ --enable-system-lcms \
+ $(use_enable !debug optimizations) \
+ $(use_enable doc docs) \
+ $(use_enable nss) \
+ $(use_enable pulseaudio pulse-java) \
+ $(use_enable kerberos system-kerberos) \
+ $(use_with pax_kernel pax paxctl-ng) \
+ ${zero_config} ${cacao_config}
+}
+
+src_compile() {
+ # Would use GENTOO_VM otherwise.
+ export ANT_RESPECT_JAVA_HOME=TRUE
+
+ # With ant >=1.8.2 all required tasks are part of ant-core
+ export ANT_TASKS="none"
+
+ emake
+}
+
+src_test() {
+ # Use Xvfb for tests
+ unset DISPLAY
+
+ Xemake check
+}
+
+src_install() {
+ local dest="/usr/$(get_libdir)/icedtea${SLOT}"
+ local ddest="${ED}/${dest}"
+ dodir "${dest}"
+
+ dodoc README NEWS AUTHORS
+ dosym /usr/share/doc/${PF} /usr/share/doc/${PN}${SLOT}
+
+ cd openjdk.build/j2sdk-image || die
+
+ # Ensures HeadlessGraphicsEnvironment is used.
+ if ! use X; then
+ rm -r jre/lib/$(get_system_arch)/xawt || die
+ fi
+
+ # Don't hide classes
+ rm lib/ct.sym || die
+
+ #402507
+ mkdir jre/.systemPrefs || die
+ touch jre/.systemPrefs/.system.lock || die
+ touch jre/.systemPrefs/.systemRootModFile || die
+
+ # doins can't handle symlinks.
+ cp -vRP bin include jre lib man "${ddest}" || die
+
+ dodoc ASSEMBLY_EXCEPTION THIRD_PARTY_README
+
+ if use doc; then
+ # java-pkg_dohtml needed for package-list #302654
+ java-pkg_dohtml -r ../docs/* || die
+ fi
+
+ if use examples; then
+ dodir "${dest}/share";
+ cp -vRP demo sample "${ddest}/share/" || die
+ fi
+
+ if use source; then
+ cp src.zip "${ddest}" || die
+ fi
+
+ # Fix the permissions.
+ find "${ddest}" \! -type l \( -perm /111 -exec chmod 755 {} \; -o -exec chmod 644 {} \; \) || die
+
+ # Needs to be done before generating cacerts
+ java-vm_set-pax-markings "${ddest}"
+
+ # We need to generate keystore - bug #273306
+ einfo "Generating cacerts file from certificates in ${EPREFIX}/usr/share/ca-certificates/"
+ mkdir "${T}/certgen" && cd "${T}/certgen" || die
+ cp "${FILESDIR}/generate-cacerts.pl" . && chmod +x generate-cacerts.pl || die
+ for c in "${EPREFIX}"/usr/share/ca-certificates/*/*.crt; do
+ openssl x509 -text -in "${c}" >> all.crt || die
+ done
+ ./generate-cacerts.pl "${ddest}/bin/keytool" all.crt || die
+ cp -vRP cacerts "${ddest}/jre/lib/security/" || die
+ chmod 644 "${ddest}/jre/lib/security/cacerts" || die
+
+ # OpenJDK7 should be able to use fontconfig instead, but wont hurt to
+ # install it anyway. Bug 390663
+ cp "${FILESDIR}"/fontconfig.Gentoo.properties.src "${T}"/fontconfig.Gentoo.properties || die
+ eprefixify "${T}"/fontconfig.Gentoo.properties
+ insinto "${dest}"/jre/lib
+ doins "${T}"/fontconfig.Gentoo.properties
+
+ set_java_env "${FILESDIR}/icedtea.env"
+ if ! use X || ! use alsa || ! use cups; then
+ java-vm_revdep-mask "${dest}"
+ fi
+ java-vm_sandbox-predict /proc/self/coredump_filter
+}
+
+pkg_preinst() {
+ if has_version "<=dev-java/icedtea-7.2.0:7"; then
+ # portage would preserve the symlink otherwise, related to bug #384397
+ rm -f "${EROOT}/usr/lib/jvm/icedtea7"
+ elog "To unify the layout and simplify scripts, the identifier of Icedtea-7*"
+ elog "has changed from 'icedtea7' to 'icedtea-7' starting from version 7.2.0-r1"
+ elog "If you had icedtea7 as system VM, the change should be automatic, however"
+ elog "build VM settings in /etc/java-config-2/build/jdk.conf are not changed"
+ elog "and the same holds for any user VM settings. Sorry for the inconvenience."
+ fi
+}
--- /dev/null Thu Jan 01 00:00:00 1970 +0000
+++ b/media-sound/mps/metadata.xml Tue Mar 25 18:26:56 2014 +0100
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<!-- <herd>some-herd</herd> -->
+<maintainer>
+ <email>da_risk@geekorum.com</email>
+</maintainer>
+</pkgmetadata>
--- /dev/null Thu Jan 01 00:00:00 1970 +0000
+++ b/media-sound/mps/mps-0.20.02.ebuild Tue Mar 25 18:26:56 2014 +0100
@@ -0,0 +1,23 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_1,3_2,3_3} )
+
+inherit distutils-r1 git-2
+
+EGIT_REPO_URI="git://github.com/np1/mps.git"
+
+DESCRIPTION="Terminal based MP3 search, playback, download"
+HOMEPAGE="https://github.com/np1/mps"
+SRC_URI=""
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+DEPEND=""
+RDEPEND="|| ( media-video/mplayer media-video/mplayer2 )"