/*

 * AboutOss is an utility library to retrieve and display

 * opensource licenses in Android applications.

 *

 * Copyright (C) 2023-2025 by Frederic-Charles Barthelery.

 *

 * This file is part of AboutOss.

 *

 * AboutOss is free software: you can redistribute it and/or modify

 * it under the terms of the GNU General Public License as published by

 * the Free Software Foundation, either version 3 of the License, or

 * (at your option) any later version.

 *

 * AboutOss is distributed in the hope that it will be useful,

 * but WITHOUT ANY WARRANTY; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

 * GNU General Public License for more details.

 *

 * You should have received a copy of the GNU General Public License

 * along with AboutOss.  If not, see <http://www.gnu.org/licenses/>.

 */

import org.jetbrains.kotlin.gradle.dsl.JvmTarget

@Suppress("DSL_SCOPE_VIOLATION") // TODO: Remove once KTIJ-19369 is fixed

plugins {

    id("com.android.application")

    kotlin("multiplatform")

    id("com.geekorum.build.source-license-checker")

    alias(libs.plugins.org.jetbrains.kotlin.compose.compiler)

    alias(libs.plugins.org.jetbrains.compose.multiplatform)

    alias(libs.plugins.org.jetbrains.kotlinx.serialization)

    alias(libs.plugins.google.gms.oss.license)

}

// workaround bug https://issuetracker.google.com/issues/275534543

buildscript {

    dependencies {

        classpath("com.android.tools.build:gradle:8.9.2")

    }

}

kotlin {

    androidTarget {

        compilerOptions {

            jvmTarget.set(JvmTarget.JVM_17)

        }

    }

    jvm("desktop") {

        mainRun {

            mainClass = "com.geekorum.aboutoss.sampleapp.MainKt"

        }

    }

    listOf(

        iosX64(),

        iosArm64(),

        iosSimulatorArm64(),

    ).forEach { iosTarget ->

        iosTarget.binaries.framework {

            baseName = "aboutoss-sample-app"

            isStatic = true

        }

    }

    sourceSets {

        commonMain.dependencies {

            implementation(project(":core"))

            implementation(project(":ui:common"))

            implementation(project(":ui:material2"))

            implementation(project(":ui:material3"))

            implementation(compose.material3)

            implementation(compose.components.resources)

            implementation(compose.components.uiToolingPreview)

            implementation(libs.org.jetbrains.androidx.lifecycle.viewmodel.compose)

        }

        androidMain.dependencies {

            api(libs.androidx.activity)

            implementation(dependencies.enforcedPlatform(libs.androidx.compose.bom))

            implementation(libs.androidx.activity.compose)

            implementation(libs.geekdroid)

        }

        val desktopMain by getting {

            dependencies {

                implementation(compose.desktop.currentOs)

                implementation(libs.kotlinx.coroutines.swing)

            }

        }

    }

}

android {

    namespace = "com.geekorum.aboutoss.sampleapp"

    compileSdk = 35

    defaultConfig {

        applicationId = "com.geekorum.aboutoss.sampleapp"

        minSdk = 24

        targetSdk = 33

        versionCode = 1

        versionName = "1.0"

        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"

        vectorDrawables {

            useSupportLibrary = true

        }

    }

    buildTypes {

        release {

            isMinifyEnabled = false

            proguardFiles(

                getDefaultProguardFile("proguard-android-optimize.txt"),

                "proguard-rules.pro"

            )

        }

    }

    compileOptions {

        sourceCompatibility = JavaVersion.VERSION_17

        targetCompatibility = JavaVersion.VERSION_17

    }

    buildFeatures {

        compose = true

        buildConfig = true

    }

    packaging {

        resources {

            excludes += "/META-INF/{AL2.0,LGPL2.1}"

        }

    }

}

dependencies {

    testImplementation(libs.junit)

    androidTestImplementation(libs.androidx.test.ext.junit)

    androidTestImplementation(libs.espresso.core)

    androidTestImplementation(platform(libs.androidx.compose.bom))

    androidTestImplementation(libs.androidx.compose.ui.test.junit4)

    debugImplementation(libs.androidx.compose.ui.tooling)

    debugImplementation(libs.androidx.compose.ui.test.manifest)

}